#! /usr/bin/env tclsh
# Copyright (c) 2021 D. Bohdan.
# License: MIT.
namespace eval tclmark {
    variable interp
    variable renders 0
    variable version 0.1.0
    namespace eval cmd {
        namespace path [namespace parent]
    }
}
proc tclmark::render {content {variables {}}} {
    variable interp
    variable renders
    incr renders
    set interp tclmark-$renders
    try {
        interp create -safe $interp
        foreach command [info commands cmd::*] {
            $interp alias \
                [namespace tail $command] \
                $command \
        }
        interp hide $interp subst
        flatten [msubst $content]
    } finally {
        catch {
            interp delete $interp
        }
    }
}
proc tclmark::msubst content {
    variable interp
    set r [interp invokehidden \
        $interp \
        subst -nobackslashes -novariables $content \
    ]
    if {$r eq $content} {
        return [list text $content]
    }
    return $r
}
proc tclmark::flatten tree {
    if {[llength $tree] != 2} {
        error [list not two elements: $tree]
    }
    lassign $tree tag data
    switch -- $tag {
        html {
            lindex $data
        }
        text {
            entities $data
        }
        tree {
            join [lmap el $data {
                flatten $el
            }] {}
        }
        default {
            error [list unknown tag: $tag]
        }
    }
}
proc tclmark::entities text {
    string map {
        & &
        < &lt;
        > &gt;
        \" &quot;
        ' &#039;
    } $text
}
proc tclmark::tree args {
    list tree $args
}
proc tclmark::cmd::b content {
    tree {html <b>} [msubst $content] {html </b>}
}
proc tclmark::cmd::i content {
    tree {html <i>} [msubst $content] {html </i>}
}
proc tclmark::run-tests {} {
    set stats [dict create total 0 passed 0 failed 0]
    proc test {name script arrow expected} {
        upvar stats stats
        dict incr stats total
        catch $script result
        set matched [switch -- $arrow {
            ->   { expr {$result eq $expected} }
            ->*  { string match $expected $result }
            ->$  { regexp -- $expected $result }
            default {
                return -code error \
                       -errorcode {JIMLIB TEST BAD-ARROW} \
                       [list unknown arrow: $arrow]
            }
        }]
        if {!$matched} {
            set error {}
            append error "\n>>>>> $name failed: [list $script]\n"
            append error "      got: [list $result]\n"
            append error " expected: [list $expected]"
            if {$arrow ne {->}} {
                append error "\n    match: $arrow"
            }
            dict incr stats failed
            puts stderr $error
            return
        }
        dict incr stats passed
    }
    test basic-1 {
        tclmark::render Test
    } -> Test
    test basic-2 {
        tclmark::render {[b Test]}
    } -> <b>Test</b>
    test basic-3 {
        tclmark::render {[i {Hello, world!}]}
    } -> {<i>Hello, world!</i>}
    test basic-4 {
        tclmark::render {[b [i Test]]}
    } -> <b><i>Test</i></b>
    test basic-5 {
        tclmark::render {[b {[i Test]}]}
    } -> <b><i>Test</i></b>
    test basic-6 {
        tclmark::render {[}
    } -> \[
    test html-1 {
        tclmark::render {<b><i>Test</i></b>}
    } -> {&lt;b&gt;&lt;i&gt;Test&lt;/i&gt;&lt;/b&gt;}
    test html-2 {
        tclmark::render {[b <script>alert('Hello!')</script>]}
    } -> {<b>&lt;script&gt;alert(&#039;Hello!&#039;)&lt;/script&gt;</b>}
    test list-1 {
        tclmark::render {[list first second third]}
    } -> {<ol><li>first</li><li>second</li><li>third</li></ol>}
    puts stderr $stats
    return [expr {[dict get $stats failed] > 0}]
}
# If this is the main script...
if {[info exists argv0] && ([file tail [info script]] eq [file tail $argv0])} {
    exit [tclmark::run-tests]
}
package provide tclmark 0

#! /bin/sh
set -e
cd "$(dirname "$(readlink -f "$0")")" || exit
echo "running $(basename "$0") in $(pwd)"
run() {
    printf "\n===== %s\n" "$*"
    "$@"
}
run ./tclkit-8.6.10 ../tclmark.tcl
run ./tclkit-8.7a3  ../tclmark.tcl

#! /bin/sh
set -e
cd "$(dirname "$(readlink -f "$0")")" || exit
echo "running $(basename "$0") in $(pwd)"
wget -O tclkit-8.6.10 http://kitcreator.rkeene.org/kits/1027aea8fcb581ff672bf7800aabc268f50c6150/tclkit
echo 'a6f52deb549d019b10dd21ed2327c3359656c891bdf63b4ea4cc853ad4c065d1  tclkit-8.6.10' >> checksum
sha256sum -c checksum && rm checksum
chmod +x tclkit*

Copyright (c) 2021 D. Bohdan and contributors listed in AUTHORS
Permission is hereby granted, free of charge, to any person obtaining a copy
of this software and associated documentation files (the "Software"), to deal
in the Software without restriction, including without limitation the rights
to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:
The above copyright notice and this permission notice shall be included in
all copies or substantial portions of the Software.
THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
THE SOFTWARE.

# The AUTHORS Certificate
# First edition, Fourteenth draft
#
# By proposing a change to this project that adds a line like
#
#     Name <E-Mail> (URL) [Working For]
#
# below, you certify:
#
# 1. All of your contributions to this project are and will be your own,
#    original work, licensed on the same terms as this project.
#
# 2. If someone else might own intellectual property in your
#    contributions, like an employer or client, you've added their legal
#    name in square brackets and got their written permission to submit
#    your contribution.
#
# 3. If you haven't added a name in square brackets, you are sure that
#    you have the legal right to license all your contributions so far
#    by yourself.
#
# 4. If you make any future contribution under different intellectual
#    property circumstances, you'll propose a change to add another line
#    to this file for that contribution.
#
# 5. The name, e-mail, and URL you've added to this file are yours. You
#    understand the project will make this file public.
D. Bohdan <see commit history> https://dbohdan.com/