{
  config,
  lib,
  ...
}: {
  home.activation.setup-allowed-signers = lib.hm.dag.entryAfter ["install-apps"] ''
    echo "* $(cat "$HOME"/.ssh/id_ed25519.pub)" > "$HOME"/.ssh/allowed_signers
  '';
  programs = {
    git = {
      enable = true;
      userEmail = "el-github@elangley.org";
      userName = "Edward Langley";
      lfs.enable = true;
      difftastic.enable = true;
      extraConfig = {
        commit = {gpgsign = true;};
        github = {user = "fiddlerwoaroof";};
        gpg = {
          format = "ssh";
          allowedSignersFile = "${config.home.homeDirectory}/.ssh/allowed_signers";
        };
        init = {defaultBranch = "main";};
        merge = {autoStash = true;};
        pull = {rebase = false;};
        rebase = {autoStash = true;};
        user = {signingkey = "${config.home.homeDirectory}/.ssh/id_ed25519.pub";};
      };
    };
  };
}

{extraFlakes, pkgs, system, ...}: {
  home.packages = [
    extraFlakes.alejandra.defaultPackage.${system}
    pkgs.clojure
    pkgs.coreutils-prefixed
    pkgs.difftastic
    pkgs.direnv
    pkgs.dtach
    pkgs.ecl
    pkgs.fwoar.gsed
    pkgs.gawk
    pkgs.gnumake
    pkgs.gnuplot
    pkgs.groff
    pkgs.htop
    pkgs.jq
    pkgs.lorri
    pkgs.mosh
    # pkgs.ncdu ## currently broken
    pkgs.nixfmt-classic
    pkgs.pandoc
    pkgs.pkg-config
    pkgs.ripgrep
    (pkgs.sbcl.overrideAttrs (_: {
      enableFeatures = [
        "sb-thread"
        "sb-core-compression"
        "sb-simd"
        "sb-xref-for-internals"
        "sb-after-xc-core"
        "sb-doc"
      ];
    }))
    pkgs.shellcheck
    pkgs.texinfoInteractive
    pkgs.tree
    pkgs.vim
    pkgs.visidata
    (pkgs.zsh
     // {
       meta =
         pkgs.zsh.meta
         // {
           outputsToInstall = pkgs.zsh.meta.outputsToInstall ++ ["info" "doc"];
         };
     })
  ];
}

{
  lib,
  config,
  pkgs,
  ...
}: {
  home.packages = [
    pkgs.crawlTiles
    pkgs.fwoar.iterm2
    pkgs.emacs-git
  ];
  home.activation.install-apps = lib.hm.dag.entryAfter ["linkGeneration"] ''
    new_nix_apps="${config.home.homeDirectory}/Applications/Nix"
    rm -rf "$new_nix_apps"
    mkdir -p "$new_nix_apps"
    find -H -L "$genProfilePath/home-files/Applications" -maxdepth 2 -name "*.app" -type d -print | while read -r app; do
      real_app=$(readlink -f "$app")
      app_name=$(basename "$app")
      target_app="$new_nix_apps/$app_name"
      echo "Link '$real_app' to '$target_app'"
      mkdir -p $target_app
      "${pkgs.xorg.lndir}"/bin/lndir "$real_app" "$target_app" 2>&1>/dev/null
      rm "$target_app/Contents/Info.plist"
      cp "$real_app/Contents/Info.plist" "$target_app/Contents/Info.plist"
    done
  '';
}