{
  pkgs ? import <nixpkgs> { },
}:
let
  package = pkgs.callPackage ./package.nix { };
in
pkgs.mkShell {
  inputsFrom = [ package ];
  packages = [
    pkgs.rust-analyzer
    pkgs.rustfmt
    pkgs.clippy
  ];
}

{
  fetchpijul,
  libsodium,
  pkg-config,
  rustPlatform,
}:
let
  pijul-src = fetchpijul {
    url = "https://nest.pijul.org/pijul/pijul";
    state = "ZMOCZOONXX53HIU2ZIP4G5XYEQCC2WJEZCWV7PGJ4GW4H3FAVIQQC";
    hash = "sha256-L+KQPjIvUvY750Yyq8VU1I1iTYCvYqPTLLenQOdYc/4=";
    name = "pijul-src";
  };
in
rustPlatform.buildRustPackage {
  pname = "tupeke";
  version = "0.1.0";
  src = ./.;
  cargoHash = "sha256-9mH5maIPeFWPNqbnVY9TYqXy7S5CxGcCjFI2ItdFVAo=";
  prePatch = ''
    sed -i 's|../pijul|${pijul-src}|g' Cargo.toml
  '';
  nativeBuildInputs = [
    pkg-config
  ];
  buildInputs = [
    libsodium
  ];
}

{
  description = "A work-in-progress pijul host and tightly integrated kanban board";
  inputs = {
    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
  };
  outputs =
    { self, nixpkgs }:
    let
      forAllSystems = nixpkgs.lib.genAttrs nixpkgs.lib.systems.flakeExposed;
      useImport =
        path:
        forAllSystems (
          system:
          let
            pkgs = nixpkgs.legacyPackages."${system}";
          in
          {
            default = import path { inherit pkgs; };
          }
        );
    in
    {
      packages = useImport ./default.nix;
      devShells = useImport ./shell.nix;
    };
}

{
  "nodes": {
    "nixpkgs": {
      "locked": {
        "lastModified": 1754725699,
        "narHash": "sha256-iAcj9T/Y+3DBy2J0N+yF9XQQQ8IEb5swLFzs23CdP88=",
        "owner": "nixos",
        "repo": "nixpkgs",
        "rev": "85dbfc7aaf52ecb755f87e577ddbe6dbbdbc1054",
        "type": "github"
      },
      "original": {
        "owner": "nixos",
        "ref": "nixos-unstable",
        "repo": "nixpkgs",
        "type": "github"
      }
    },
    "root": {
      "inputs": {
        "nixpkgs": "nixpkgs"
      }
    }
  },
  "root": "root",
  "version": 7
}

{
  pkgs ? import <nixpkgs> { },
}:
pkgs.callPackage ./package.nix { }